Overview
xDAI Balance
0 xDAIxDAI Value
$0.00More Info
Private Name Tags
ContractCreator
Loading...
Loading
Contract Name:
xKlerosLiquidExtraViews
Compiler Version
v0.4.26+commit.4563c3fc
Optimization Enabled:
Yes with 200 runs
Other Settings:
default evmVersion
Contract Source Code (Solidity)
/**
*Submitted for verification at gnosisscan.io on 2022-08-04
*/
// File: contracts/kleros/xKlerosLiquidExtraViews.sol
/**
* https://contributing.kleros.io/smart-contract-workflow
* @reviewers: [@hbarcelos]
* @auditors: []
* @bounties: []
* @deployments: []
*/
pragma solidity ^0.4.24;
/**
* @title xKlerosLiquidExtraViews
* @dev This contract is an adaption of Mainnet's xKlerosLiquidExtraViews (https://github.com/kleros/kleros/blob/69cfbfb2128c29f1625b3a99a3183540772fda08/contracts/kleros/KlerosLiquidExtraViews.sol)
* for xDai chain.
*/
contract xKlerosLiquidExtraViews {
/* Storage */
xKlerosLiquid public klerosLiquid;
/* Constructor */
/** @dev Constructs the xKlerosLiquidExtraViews contract.
* @param _klerosLiquid The address of KlerosLiquid on xDai.
*/
constructor(xKlerosLiquid _klerosLiquid) public {
klerosLiquid = _klerosLiquid;
}
/* External Views */
/** @dev Gets the stake of a specified juror in a specified subcourt, taking into account delayed set stakes.
* @param _account The address of the juror.
* @param _subcourtID The ID of the subcourt.
* @return The stake.
*/
function stakeOf(address _account, uint96 _subcourtID) external view returns(uint stake) {
(
uint96[] memory subcourtIDs,
,
,
uint[] memory subcourtStakes
) = getJuror(_account);
for (uint i = 0; i < subcourtIDs.length; i++) {
if (_subcourtID + 1 == subcourtIDs[i]) {
stake = subcourtStakes[i];
}
}
}
/* Public Views */
/** @dev Gets a specified juror's properties, taking into account delayed set stakes. Note that subcourt IDs are shifted by 1 so that 0 can be "empty".
* @param _account The address of the juror.
* @return The juror's properties, taking into account delayed set stakes.
*/
function getJuror(address _account) public view returns(
uint96[] subcourtIDs,
uint stakedTokens,
uint lockedTokens,
uint[] subcourtStakes
) {
subcourtIDs = new uint96[](klerosLiquid.MAX_STAKE_PATHS());
(stakedTokens, lockedTokens) = klerosLiquid.jurors(_account);
subcourtStakes = new uint[](klerosLiquid.MAX_STAKE_PATHS());
uint96[] memory actualSubcourtIDs = klerosLiquid.getJuror(_account);
for (uint i = 0; i < actualSubcourtIDs.length; i++) {
subcourtIDs[i] = actualSubcourtIDs[i] + 1;
subcourtStakes[i] = klerosLiquid.stakeOf(_account, actualSubcourtIDs[i]);
}
for (i = klerosLiquid.nextDelayedSetStake(); i <= klerosLiquid.lastDelayedSetStake(); i++) {
(address account, uint96 subcourtID, uint128 stake) = klerosLiquid.delayedSetStakes(i);
if (_account == account) {
if (stake == 0) {
for (uint j = 0; j < subcourtIDs.length; j++) {
if (subcourtID == subcourtIDs[j]) {
subcourtIDs[j] = 0;
subcourtStakes[j] = 0;
break;
}
}
} else {
for (j = 0; j < subcourtIDs.length * 2; j++) {
if ((j < subcourtIDs.length && subcourtID + 1 == subcourtIDs[j]) || (j >= subcourtIDs.length && subcourtIDs[j % subcourtIDs.length] == 0)) {
(
,
,
uint courtMinStake,
,
,
) = klerosLiquid.courts(j % subcourtIDs.length);
if (
courtMinStake <= stake &&
klerosLiquid.pinakion().balanceOf(_account) >= stakedTokens - subcourtStakes[j % subcourtIDs.length] + stake
) {
subcourtIDs[j % subcourtIDs.length] = subcourtID + 1;
stakedTokens = stakedTokens - subcourtStakes[j % subcourtIDs.length] + stake;
subcourtStakes[j % subcourtIDs.length] = stake;
}
}
}
}
}
}
}
}
// File: openzeppelin-eth/contracts/zos-lib/Initializable.sol
pragma solidity ^0.4.24;
/**
* @title Initializable
*
* @dev Helper contract to support initializer functions. To use it, replace
* the constructor with a function that has the `initializer` modifier.
* WARNING: Unlike constructors, initializer functions must be manually
* invoked. This applies both to deploying an Initializable contract, as well
* as extending an Initializable contract via inheritance.
* WARNING: When used with inheritance, manual care must be taken to not invoke
* a parent initializer twice, or ensure that all initializers are idempotent,
* because this is not dealt with automatically as with constructors.
*/
contract Initializable {
/**
* @dev Indicates that the contract has been initialized.
*/
bool private initialized;
/**
* @dev Indicates that the contract is in the process of being initialized.
*/
bool private initializing;
/**
* @dev Modifier to use in the initializer function of a contract.
*/
modifier initializer() {
require(initializing || isConstructor() || !initialized, "Contract instance has already been initialized");
bool wasInitializing = initializing;
initializing = true;
initialized = true;
_;
initializing = wasInitializing;
}
/// @dev Returns true if and only if the function is running in the constructor
function isConstructor() private view returns (bool) {
// extcodesize checks the size of the code stored in an address, and
// address returns the current address. Since the code is still not
// deployed when running a constructor, any checks on its code size will
// yield zero, making it an effective way to detect if a contract is
// under construction or not.
uint256 cs;
assembly { cs := extcodesize(address) }
return cs == 0;
}
// Reserved storage space to allow for layout changes in the future.
uint256[50] private ______gap;
}
// File: minimetoken/contracts/TokenController.sol
pragma solidity ^0.4.18;
/// @dev The token controller contract must implement these functions
contract TokenController {
/// @notice Called when `_owner` sends ether to the MiniMe Token contract
/// @param _owner The address that sent the ether to create tokens
/// @return True if the ether is accepted, false if it throws
function proxyPayment(address _owner) public payable returns(bool);
/// @notice Notifies the controller about a token transfer allowing the
/// controller to react if desired
/// @param _from The origin of the transfer
/// @param _to The destination of the transfer
/// @param _amount The amount of the transfer
/// @return False if the controller does not authorize the transfer
function onTransfer(address _from, address _to, uint _amount) public returns(bool);
/// @notice Notifies the controller about an approval allowing the
/// controller to react if desired
/// @param _owner The address that calls `approve()`
/// @param _spender The spender in the `approve()` call
/// @param _amount The amount in the `approve()` call
/// @return False if the controller does not authorize the approval
function onApprove(address _owner, address _spender, uint _amount) public
returns(bool);
}
// File: openzeppelin-eth/contracts/math/SafeMath.sol
pragma solidity ^0.4.24;
/**
* @title SafeMath
* @dev Math operations with safety checks that revert on error
*/
library SafeMath {
/**
* @dev Multiplies two numbers, reverts on overflow.
*/
function mul(uint256 a, uint256 b) internal pure returns (uint256) {
// Gas optimization: this is cheaper than requiring 'a' not being zero, but the
// benefit is lost if 'b' is also tested.
// See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522
if (a == 0) {
return 0;
}
uint256 c = a * b;
require(c / a == b);
return c;
}
/**
* @dev Integer division of two numbers truncating the quotient, reverts on division by zero.
*/
function div(uint256 a, uint256 b) internal pure returns (uint256) {
require(b > 0); // Solidity only automatically asserts when dividing by 0
uint256 c = a / b;
// assert(a == b * c + a % b); // There is no case in which this doesn't hold
return c;
}
/**
* @dev Subtracts two numbers, reverts on overflow (i.e. if subtrahend is greater than minuend).
*/
function sub(uint256 a, uint256 b) internal pure returns (uint256) {
require(b <= a);
uint256 c = a - b;
return c;
}
/**
* @dev Adds two numbers, reverts on overflow.
*/
function add(uint256 a, uint256 b) internal pure returns (uint256) {
uint256 c = a + b;
require(c >= a);
return c;
}
/**
* @dev Divides two numbers and returns the remainder (unsigned integer modulo),
* reverts when dividing by zero.
*/
function mod(uint256 a, uint256 b) internal pure returns (uint256) {
require(b != 0);
return a % b;
}
}
// File: contracts/interfaces/IERC677.sol
pragma solidity ^0.4.24;
interface IERC677 {
function transfer(address _to, uint256 _value) external returns (bool);
function transferFrom(
address _from,
address _to,
uint256 _value
) external returns (bool);
function approve(address _spender, uint256 _value) external returns (bool);
}
// File: contracts/interfaces/ITokenBridge.sol
pragma solidity ^0.4.24;
interface ITokenBridge {
function relayTokens(
IERC677 token,
address _receiver,
uint256 _value
) external;
}
// File: contracts/tokens/WrappedPinakion.sol
/**
* https://contributing.kleros.io/smart-contract-workflow
* @authors: [@fnanni-0]
* @reviewers: [@unknownunknown1, @MerlinEgalite, @hbarcelos, @shalzz]
* @auditors: []
* @bounties: []
* @deployments: []
*/
pragma solidity ^0.4.24;
contract WrappedPinakion is Initializable {
using SafeMath for uint256;
/* Events */
/**
* @notice Emitted when `value` tokens are moved from one account (`from`) to another (`to`).
* @dev Notice that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @notice Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
/* Storage */
mapping(address => uint256) private balances;
mapping(address => mapping(address => uint256)) public allowance;
/// @notice Total supply of the token. Equals the total xPinakion deposit into the contract.
uint256 public totalSupply;
/// @notice Name of the token.
string public name;
/// @notice Symbol of the token.
string public symbol;
/// @notice Number of decimals of the token.
uint8 public decimals;
/// @notice The token's controller.
address public controller;
/// @notice Bridged PNK on xDai to be wrapped. This token is upgradeable.
IERC677 public xPinakion;
/// @notice xDai Token Bridge. The Token Bridge is upgradeable.
ITokenBridge public tokenBridge;
/* Modifiers */
/// @dev Verifies that the sender has ability to modify controlled parameters.
modifier onlyController() {
require(controller == msg.sender, "The caller is not the controller.");
_;
}
/* Initializer */
/**
* @dev Constructor.
* @param _name for the wrapped PNK on the home chain.
* @param _symbol for wrapped PNK ticker on the home chain.
* @param _xPinakion the home PNK contract which is already bridged to the foreign PNK contract.
* @param _tokenBridge the TokenBridge contract.
*/
function initialize(
string memory _name,
string memory _symbol,
IERC677 _xPinakion,
ITokenBridge _tokenBridge
) public initializer {
name = _name;
symbol = _symbol;
decimals = 18;
xPinakion = _xPinakion;
tokenBridge = _tokenBridge;
controller = msg.sender;
}
/* External */
/**
* @notice Changes `controller` to `_controller`.
* @param _controller The new controller of the contract
*/
function changeController(address _controller) external onlyController {
controller = _controller;
}
/**
* @notice Converts bridged PNK (xPinakion) into wrapped PNK which can be staked in KlerosLiquid.
* @param _amount The amount of wrapped pinakions to mint.
*/
function deposit(uint256 _amount) external {
_mint(msg.sender, _amount);
require(
xPinakion.transferFrom(msg.sender, address(this), _amount),
"Sender does not have enough approved funds."
);
}
/**
* @notice IERC20 Receiver functionality.
* @dev Converts bridged PNK (xPinakion) into wrapped PNK which can be staked in KlerosLiquid.
* If the tokenBridge is calling this function, then this contract has already received
* the xPinakion tokens. Notice that the Home bridge calls onTokenBridge as a result of
* someone invoking `relayTokensAndCall()` on the Foreign bridge contract.
* @param _token The token address the _amount belongs to.
* @param _amount The amount of wrapped PNK to mint.
* @param _data Calldata containing the address of the recipient.
* Notice that the address has to be padded to the right 32 bytes.
*/
function onTokenBridged(
address _token,
uint256 _amount,
bytes _data
) external {
require(msg.sender == address(tokenBridge), "Sender not authorized.");
require(_token == address(xPinakion), "Token bridged is not xPinakion.");
address recipient;
assembly {
recipient := calldataload(0x84)
}
_mint(recipient, _amount);
}
/**
* @notice Converts wrapped PNK back into bridged PNK (xPinakion).
* @param _amount The amount of bridged PNK to withdraw.
*/
function withdraw(uint256 _amount) external {
_burn(_amount);
require(xPinakion.transfer(msg.sender, _amount), "The `transfer` function must not fail.");
}
/**
* @notice Converts wrapped PNK back into PNK using the Token Bridge.
* @dev This function is not strictly needed, but it provides a good UX to users who want to get their Mainnet's PNK back.
* What normally takes 3 transactions, here is done in one go.
* Notice that the PNK have to be claimed on Mainnet's TokenBridge by the receiver.
* @param _amount The amount of PNK to withdraw.
* @param _receiver The address which will receive the PNK back in the foreign chain.
*/
function withdrawAndConvertToPNK(uint256 _amount, address _receiver) external {
_burn(_amount);
// Using approve is safe here, because this contract approves the bridge to spend the tokens and triggers the relay immediately.
xPinakion.approve(address(tokenBridge), _amount);
tokenBridge.relayTokens(xPinakion, _receiver, _amount);
}
/**
* @notice Moves `_amount` tokens from the caller's account to `_recipient`.
* @param _recipient The entity receiving the funds.
* @param _amount The amount to tranfer in base units.
* @return True on success.
*/
function transfer(address _recipient, uint256 _amount) public returns (bool) {
if (isContract(controller)) {
require(
TokenController(controller).onTransfer(msg.sender, _recipient, _amount),
"Token controller rejects transfer."
);
}
balances[msg.sender] = balances[msg.sender].sub(_amount); // ERC20: transfer amount exceeds balance
balances[_recipient] = balances[_recipient].add(_amount);
emit Transfer(msg.sender, _recipient, _amount);
return true;
}
/**
* @notice Moves `_amount` tokens from `_sender` to `_recipient` using the
* allowance mechanism. `_amount` is then deducted from the caller's allowance.
* @param _sender The entity to take the funds from.
* @param _recipient The entity receiving the funds.
* @param _amount The amount to tranfer in base units.
* @return True on success.
*/
function transferFrom(
address _sender,
address _recipient,
uint256 _amount
) public returns (bool) {
if (isContract(controller)) {
require(
TokenController(controller).onTransfer(_sender, _recipient, _amount),
"Token controller rejects transfer."
);
}
/** The controller of this contract can move tokens around at will,
* this is important to recognize! Confirm that you trust the
* controller of this contract, which in most situations should be
* another open source smart contract or 0x0.
*/
if (msg.sender != controller) {
allowance[_sender][msg.sender] = allowance[_sender][msg.sender].sub(_amount); // ERC20: transfer amount exceeds allowance.
}
balances[_sender] = balances[_sender].sub(_amount); // ERC20: transfer amount exceeds balance
balances[_recipient] = balances[_recipient].add(_amount);
emit Transfer(_sender, _recipient, _amount);
return true;
}
/**
* @notice Approves `_spender` to spend `_amount`.
* @param _spender The entity allowed to spend funds.
* @param _amount The amount of base units the entity will be allowed to spend.
* @return True on success.
*/
function approve(address _spender, uint256 _amount) public returns (bool) {
// Alerts the token controller of the approve function call
if (isContract(controller)) {
require(
TokenController(controller).onApprove(msg.sender, _spender, _amount),
"Token controller does not approve."
);
}
allowance[msg.sender][_spender] = _amount;
emit Approval(msg.sender, _spender, _amount);
return true;
}
/**
* @notice Increases the `_spender` allowance by `_addedValue`.
* @param _spender The entity allowed to spend funds.
* @param _addedValue The amount of extra base units the entity will be allowed to spend.
* @return True on success.
*/
function increaseAllowance(address _spender, uint256 _addedValue) public returns (bool) {
uint256 newAllowance = allowance[msg.sender][_spender].add(_addedValue);
// Alerts the token controller of the approve function call
if (isContract(controller)) {
require(
TokenController(controller).onApprove(msg.sender, _spender, newAllowance),
"Token controller does not approve."
);
}
allowance[msg.sender][_spender] = newAllowance;
emit Approval(msg.sender, _spender, newAllowance);
return true;
}
/**
* @notice Decreases the `_spender` allowance by `_subtractedValue`.
* @param _spender The entity whose spending allocation will be reduced.
* @param _subtractedValue The reduction of spending allocation in base units.
* @return True on success.
*/
function decreaseAllowance(address _spender, uint256 _subtractedValue) public returns (bool) {
uint256 newAllowance = allowance[msg.sender][_spender].sub(_subtractedValue); // ERC20: decreased allowance below zero
// Alerts the token controller of the approve function call
if (isContract(controller)) {
require(
TokenController(controller).onApprove(msg.sender, _spender, newAllowance),
"Token controller does not approve."
);
}
allowance[msg.sender][_spender] = newAllowance;
emit Approval(msg.sender, _spender, newAllowance);
return true;
}
/* Internal */
/**
* @dev Internal function that mints an amount of the token and assigns it to
* an account. This encapsulates the modification of balances such that the
* proper events are emitted.
* @param _recipient The address which will receive the minted tokens.
* @param _amount The amount that will be created.
*/
function _mint(address _recipient, uint256 _amount) internal {
totalSupply = totalSupply.add(_amount);
balances[_recipient] = balances[_recipient].add(_amount);
emit Transfer(address(0x0), _recipient, _amount);
}
/**
* @dev Destroys `_amount` tokens from the caller. Cannot burn locked tokens.
* @param _amount The quantity of tokens to burn in base units.
*/
function _burn(uint256 _amount) internal {
if (isContract(controller)) {
require(
TokenController(controller).onTransfer(msg.sender, address(0x0), _amount),
"Token controller rejects transfer."
);
}
balances[msg.sender] = balances[msg.sender].sub(_amount); // ERC20: burn amount exceeds balance
totalSupply = totalSupply.sub(_amount);
emit Transfer(msg.sender, address(0x0), _amount);
}
/**
* @dev Internal function to determine if an address is a contract.
* @param _addr The address being queried.
* @return True if `_addr` is a contract.
*/
function isContract(address _addr) internal view returns (bool) {
uint256 size;
if (_addr == 0) return false;
assembly {
size := extcodesize(_addr)
}
return size > 0;
}
/* Getters */
/**
* @dev Gets the balance of the specified address.
* @param _owner The address to query the balance of.
* @return uint256 value representing the amount owned by the passed address.
*/
function balanceOf(address _owner) public view returns (uint256) {
return balances[_owner];
}
}
// File: contracts/interfaces/IRandomAuRa.sol
pragma solidity ^0.4.24;
///@dev See https://blockscout.com/poa/xdai/address/0x5870b0527DeDB1cFBD9534343Feda1a41Ce47766/contracts
///@dev Sokol testnet: https://blockscout.com/poa/sokol/address/0x8f2b78169B0970F11a762e56659Db52B59CBCf1B/contracts
interface IRandomAuRa {
function currentSeed() external view returns (uint256);
function isCommitPhase() external view returns (bool);
function nextCommitPhaseStartBlock() external view returns (uint256);
function collectRoundLength() external view returns (uint256);
}
// File: @kleros/kleros/contracts/data-structures/SortitionSumTreeFactory.sol
/**
* @authors: [@epiqueras]
* @reviewers: [@clesaege, @unknownunknown1, @ferittuncer, @remedcu]
* @auditors: []
* @bounties: [{ duration: 28 days, link: https://github.com/kleros/kleros/issues/115, maxPayout: 50 ETH }]
* @deployments: [ https://etherscan.io/address/0x180eba68d164c3f8c3f6dc354125ebccf4dfcb86 ]
*/
pragma solidity ^0.4.24;
/**
* @title SortitionSumTreeFactory
* @author Enrique Piqueras - <[email protected]>
* @dev A factory of trees that keep track of staked values for sortition.
*/
library SortitionSumTreeFactory {
/* Structs */
struct SortitionSumTree {
uint K; // The maximum number of childs per node.
// We use this to keep track of vacant positions in the tree after removing a leaf. This is for keeping the tree as balanced as possible without spending gas on moving nodes around.
uint[] stack;
uint[] nodes;
// Two-way mapping of IDs to node indexes. Note that node index 0 is reserved for the root node, and means the ID does not have a node.
mapping(bytes32 => uint) IDsToNodeIndexes;
mapping(uint => bytes32) nodeIndexesToIDs;
}
/* Storage */
struct SortitionSumTrees {
mapping(bytes32 => SortitionSumTree) sortitionSumTrees;
}
/* Public */
/**
* @dev Create a sortition sum tree at the specified key.
* @param _key The key of the new tree.
* @param _K The number of children each node in the tree should have.
*/
function createTree(SortitionSumTrees storage self, bytes32 _key, uint _K) public {
SortitionSumTree storage tree = self.sortitionSumTrees[_key];
require(tree.K == 0, "Tree already exists.");
require(_K > 1, "K must be greater than one.");
tree.K = _K;
tree.stack.length = 0;
tree.nodes.length = 0;
tree.nodes.push(0);
}
/**
* @dev Set a value of a tree.
* @param _key The key of the tree.
* @param _value The new value.
* @param _ID The ID of the value.
* `O(log_k(n))` where
* `k` is the maximum number of childs per node in the tree,
* and `n` is the maximum number of nodes ever appended.
*/
function set(SortitionSumTrees storage self, bytes32 _key, uint _value, bytes32 _ID) public {
SortitionSumTree storage tree = self.sortitionSumTrees[_key];
uint treeIndex = tree.IDsToNodeIndexes[_ID];
if (treeIndex == 0) { // No existing node.
if (_value != 0) { // Non zero value.
// Append.
// Add node.
if (tree.stack.length == 0) { // No vacant spots.
// Get the index and append the value.
treeIndex = tree.nodes.length;
tree.nodes.push(_value);
// Potentially append a new node and make the parent a sum node.
if (treeIndex != 1 && (treeIndex - 1) % tree.K == 0) { // Is first child.
uint parentIndex = treeIndex / tree.K;
bytes32 parentID = tree.nodeIndexesToIDs[parentIndex];
uint newIndex = treeIndex + 1;
tree.nodes.push(tree.nodes[parentIndex]);
delete tree.nodeIndexesToIDs[parentIndex];
tree.IDsToNodeIndexes[parentID] = newIndex;
tree.nodeIndexesToIDs[newIndex] = parentID;
}
} else { // Some vacant spot.
// Pop the stack and append the value.
treeIndex = tree.stack[tree.stack.length - 1];
tree.stack.length--;
tree.nodes[treeIndex] = _value;
}
// Add label.
tree.IDsToNodeIndexes[_ID] = treeIndex;
tree.nodeIndexesToIDs[treeIndex] = _ID;
updateParents(self, _key, treeIndex, true, _value);
}
} else { // Existing node.
if (_value == 0) { // Zero value.
// Remove.
// Remember value and set to 0.
uint value = tree.nodes[treeIndex];
tree.nodes[treeIndex] = 0;
// Push to stack.
tree.stack.push(treeIndex);
// Clear label.
delete tree.IDsToNodeIndexes[_ID];
delete tree.nodeIndexesToIDs[treeIndex];
updateParents(self, _key, treeIndex, false, value);
} else if (_value != tree.nodes[treeIndex]) { // New, non zero value.
// Set.
bool plusOrMinus = tree.nodes[treeIndex] <= _value;
uint plusOrMinusValue = plusOrMinus ? _value - tree.nodes[treeIndex] : tree.nodes[treeIndex] - _value;
tree.nodes[treeIndex] = _value;
updateParents(self, _key, treeIndex, plusOrMinus, plusOrMinusValue);
}
}
}
/* Public Views */
/**
* @dev Query the leaves of a tree. Note that if `startIndex == 0`, the tree is empty and the root node will be returned.
* @param _key The key of the tree to get the leaves from.
* @param _cursor The pagination cursor.
* @param _count The number of items to return.
* @return startIndex The index at which leaves start.
* @return values The values of the returned leaves.
* @return hasMore Whether there are more for pagination.
* `O(n)` where
* `n` is the maximum number of nodes ever appended.
*/
function queryLeafs(
SortitionSumTrees storage self,
bytes32 _key,
uint _cursor,
uint _count
) public view returns(uint startIndex, uint[] values, bool hasMore) {
SortitionSumTree storage tree = self.sortitionSumTrees[_key];
// Find the start index.
for (uint i = 0; i < tree.nodes.length; i++) {
if ((tree.K * i) + 1 >= tree.nodes.length) {
startIndex = i;
break;
}
}
// Get the values.
uint loopStartIndex = startIndex + _cursor;
values = new uint[](loopStartIndex + _count > tree.nodes.length ? tree.nodes.length - loopStartIndex : _count);
uint valuesIndex = 0;
for (uint j = loopStartIndex; j < tree.nodes.length; j++) {
if (valuesIndex < _count) {
values[valuesIndex] = tree.nodes[j];
valuesIndex++;
} else {
hasMore = true;
break;
}
}
}
/**
* @dev Draw an ID from a tree using a number. Note that this function reverts if the sum of all values in the tree is 0.
* @param _key The key of the tree.
* @param _drawnNumber The drawn number.
* @return ID The drawn ID.
* `O(k * log_k(n))` where
* `k` is the maximum number of childs per node in the tree,
* and `n` is the maximum number of nodes ever appended.
*/
function draw(SortitionSumTrees storage self, bytes32 _key, uint _drawnNumber) public view returns(bytes32 ID) {
SortitionSumTree storage tree = self.sortitionSumTrees[_key];
uint treeIndex = 0;
uint currentDrawnNumber = _drawnNumber % tree.nodes[0];
while ((tree.K * treeIndex) + 1 < tree.nodes.length) // While it still has children.
for (uint i = 1; i <= tree.K; i++) { // Loop over children.
uint nodeIndex = (tree.K * treeIndex) + i;
uint nodeValue = tree.nodes[nodeIndex];
if (currentDrawnNumber >= nodeValue) currentDrawnNumber -= nodeValue; // Go to the next child.
else { // Pick this child.
treeIndex = nodeIndex;
break;
}
}
ID = tree.nodeIndexesToIDs[treeIndex];
}
/** @dev Gets a specified ID's associated value.
* @param _key The key of the tree.
* @param _ID The ID of the value.
* @return value The associated value.
*/
function stakeOf(SortitionSumTrees storage self, bytes32 _key, bytes32 _ID) public view returns(uint value) {
SortitionSumTree storage tree = self.sortitionSumTrees[_key];
uint treeIndex = tree.IDsToNodeIndexes[_ID];
if (treeIndex == 0) value = 0;
else value = tree.nodes[treeIndex];
}
/* Private */
/**
* @dev Update all the parents of a node.
* @param _key The key of the tree to update.
* @param _treeIndex The index of the node to start from.
* @param _plusOrMinus Wether to add (true) or substract (false).
* @param _value The value to add or substract.
* `O(log_k(n))` where
* `k` is the maximum number of childs per node in the tree,
* and `n` is the maximum number of nodes ever appended.
*/
function updateParents(SortitionSumTrees storage self, bytes32 _key, uint _treeIndex, bool _plusOrMinus, uint _value) private {
SortitionSumTree storage tree = self.sortitionSumTrees[_key];
uint parentIndex = _treeIndex;
while (parentIndex != 0) {
parentIndex = (parentIndex - 1) / tree.K;
tree.nodes[parentIndex] = _plusOrMinus ? tree.nodes[parentIndex] + _value : tree.nodes[parentIndex] - _value;
}
}
}
// File: @kleros/kleros-interaction/contracts/standard/arbitration/Arbitrator.sol
/**
* @authors: [@clesaege]
* @reviewers: [@remedcu]
* @auditors: []
* @bounties: []
* @deployments: []
*/
pragma solidity ^0.4.15;
/** @title Arbitrator
* Arbitrator abstract contract.
* When developing arbitrator contracts we need to:
* -Define the functions for dispute creation (createDispute) and appeal (appeal). Don't forget to store the arbitrated contract and the disputeID (which should be unique, use nbDisputes).
* -Define the functions for cost display (arbitrationCost and appealCost).
* -Allow giving rulings. For this a function must call arbitrable.rule(disputeID, ruling).
*/
contract Arbitrator {
enum DisputeStatus {Waiting, Appealable, Solved}
modifier requireArbitrationFee(bytes _extraData) {
require(msg.value >= arbitrationCost(_extraData), "Not enough ETH to cover arbitration costs.");
_;
}
modifier requireAppealFee(uint _disputeID, bytes _extraData) {
require(msg.value >= appealCost(_disputeID, _extraData), "Not enough ETH to cover appeal costs.");
_;
}
/** @dev To be raised when a dispute is created.
* @param _disputeID ID of the dispute.
* @param _arbitrable The contract which created the dispute.
*/
event DisputeCreation(uint indexed _disputeID, Arbitrable indexed _arbitrable);
/** @dev To be raised when a dispute can be appealed.
* @param _disputeID ID of the dispute.
*/
event AppealPossible(uint indexed _disputeID, Arbitrable indexed _arbitrable);
/** @dev To be raised when the current ruling is appealed.
* @param _disputeID ID of the dispute.
* @param _arbitrable The contract which created the dispute.
*/
event AppealDecision(uint indexed _disputeID, Arbitrable indexed _arbitrable);
/** @dev Create a dispute. Must be called by the arbitrable contract.
* Must be paid at least arbitrationCost(_extraData).
* @param _choices Amount of choices the arbitrator can make in this dispute.
* @param _extraData Can be used to give additional info on the dispute to be created.
* @return disputeID ID of the dispute created.
*/
function createDispute(uint _choices, bytes _extraData) public requireArbitrationFee(_extraData) payable returns(uint disputeID) {}
/** @dev Compute the cost of arbitration. It is recommended not to increase it often, as it can be highly time and gas consuming for the arbitrated contracts to cope with fee augmentation.
* @param _extraData Can be used to give additional info on the dispute to be created.
* @return fee Amount to be paid.
*/
function arbitrationCost(bytes _extraData) public view returns(uint fee);
/** @dev Appeal a ruling. Note that it has to be called before the arbitrator contract calls rule.
* @param _disputeID ID of the dispute to be appealed.
* @param _extraData Can be used to give extra info on the appeal.
*/
function appeal(uint _disputeID, bytes _extraData) public requireAppealFee(_disputeID,_extraData) payable {
emit AppealDecision(_disputeID, Arbitrable(msg.sender));
}
/** @dev Compute the cost of appeal. It is recommended not to increase it often, as it can be higly time and gas consuming for the arbitrated contracts to cope with fee augmentation.
* @param _disputeID ID of the dispute to be appealed.
* @param _extraData Can be used to give additional info on the dispute to be created.
* @return fee Amount to be paid.
*/
function appealCost(uint _disputeID, bytes _extraData) public view returns(uint fee);
/** @dev Compute the start and end of the dispute's current or next appeal period, if possible.
* @param _disputeID ID of the dispute.
* @return The start and end of the period.
*/
function appealPeriod(uint _disputeID) public view returns(uint start, uint end) {}
/** @dev Return the status of a dispute.
* @param _disputeID ID of the dispute to rule.
* @return status The status of the dispute.
*/
function disputeStatus(uint _disputeID) public view returns(DisputeStatus status);
/** @dev Return the current ruling of a dispute. This is useful for parties to know if they should appeal.
* @param _disputeID ID of the dispute.
* @return ruling The ruling which has been given or the one which will be given if there is no appeal.
*/
function currentRuling(uint _disputeID) public view returns(uint ruling);
}
// File: @kleros/kleros-interaction/contracts/standard/arbitration/IArbitrable.sol
/**
* @authors: [@epiqueras]
* @reviewers: [@remedcu]
* @auditors: []
* @bounties: []
* @deployments: []
*/
pragma solidity ^0.4.15;
/**
* @title IArbitrable
* @author Enrique Piqueras - <[email protected]>
* Bug Bounties: This code hasn't undertaken a bug bounty program yet.
*/
/** @title IArbitrable
* Arbitrable interface.
* When developing arbitrable contracts, we need to:
* -Define the action taken when a ruling is received by the contract. We should do so in executeRuling.
* -Allow dispute creation. For this a function must:
* -Call arbitrator.createDispute.value(_fee)(_choices,_extraData);
* -Create the event Dispute(_arbitrator,_disputeID,_rulingOptions);
*/
interface IArbitrable {
/** @dev To be emmited when meta-evidence is submitted.
* @param _metaEvidenceID Unique identifier of meta-evidence.
* @param _evidence A link to the meta-evidence JSON.
*/
event MetaEvidence(uint indexed _metaEvidenceID, string _evidence);
/** @dev To be emmited when a dispute is created to link the correct meta-evidence to the disputeID
* @param _arbitrator The arbitrator of the contract.
* @param _disputeID ID of the dispute in the Arbitrator contract.
* @param _metaEvidenceID Unique identifier of meta-evidence.
* @param _evidenceGroupID Unique identifier of the evidence group that is linked to this dispute.
*/
event Dispute(Arbitrator indexed _arbitrator, uint indexed _disputeID, uint _metaEvidenceID, uint _evidenceGroupID);
/** @dev To be raised when evidence are submitted. Should point to the ressource (evidences are not to be stored on chain due to gas considerations).
* @param _arbitrator The arbitrator of the contract.
* @param _evidenceGroupID Unique identifier of the evidence group the evidence belongs to.
* @param _party The address of the party submiting the evidence. Note that 0x0 refers to evidence not submitted by any party.
* @param _evidence A URI to the evidence JSON file whose name should be its keccak256 hash followed by .json.
*/
event Evidence(Arbitrator indexed _arbitrator, uint indexed _evidenceGroupID, address indexed _party, string _evidence);
/** @dev To be raised when a ruling is given.
* @param _arbitrator The arbitrator giving the ruling.
* @param _disputeID ID of the dispute in the Arbitrator contract.
* @param _ruling The ruling which was given.
*/
event Ruling(Arbitrator indexed _arbitrator, uint indexed _disputeID, uint _ruling);
/** @dev Give a ruling for a dispute. Must be called by the arbitrator.
* The purpose of this function is to ensure that the address calling it has the right to rule on the contract.
* @param _disputeID ID of the dispute in the Arbitrator contract.
* @param _ruling Ruling given by the arbitrator. Note that 0 is reserved for "Not able/wanting to make a decision".
*/
function rule(uint _disputeID, uint _ruling) public;
}
// File: @kleros/kleros-interaction/contracts/standard/arbitration/IArbitrable.sol
/**
* @authors: [@clesaege]
* @reviewers: [@remedcu]
* @auditors: []
* @bounties: []
* @deployments: []
*/
pragma solidity ^0.4.15;
/** @title Arbitrable
* Arbitrable abstract contract.
* When developing arbitrable contracts, we need to:
* -Define the action taken when a ruling is received by the contract. We should do so in executeRuling.
* -Allow dispute creation. For this a function must:
* -Call arbitrator.createDispute.value(_fee)(_choices,_extraData);
* -Create the event Dispute(_arbitrator,_disputeID,_rulingOptions);
*/
contract Arbitrable is IArbitrable {
Arbitrator public arbitrator;
bytes public arbitratorExtraData; // Extra data to require particular dispute and appeal behaviour.
modifier onlyArbitrator {require(msg.sender == address(arbitrator), "Can only be called by the arbitrator."); _;}
/** @dev Constructor. Choose the arbitrator.
* @param _arbitrator The arbitrator of the contract.
* @param _arbitratorExtraData Extra data for the arbitrator.
*/
constructor(Arbitrator _arbitrator, bytes _arbitratorExtraData) public {
arbitrator = _arbitrator;
arbitratorExtraData = _arbitratorExtraData;
}
/** @dev Give a ruling for a dispute. Must be called by the arbitrator.
* The purpose of this function is to ensure that the address calling it has the right to rule on the contract.
* @param _disputeID ID of the dispute in the Arbitrator contract.
* @param _ruling Ruling given by the arbitrator. Note that 0 is reserved for "Not able/wanting to make a decision".
*/
function rule(uint _disputeID, uint _ruling) public onlyArbitrator {
emit Ruling(Arbitrator(msg.sender),_disputeID,_ruling);
executeRuling(_disputeID,_ruling);
}
/** @dev Execute a ruling of a dispute.
* @param _disputeID ID of the dispute in the Arbitrator contract.
* @param _ruling Ruling given by the arbitrator. Note that 0 is reserved for "Not able/wanting to make a decision".
*/
function executeRuling(uint _disputeID, uint _ruling) internal;
}
// File: contracts/kleros/xKlerosLiquid.sol
/**
* https://contributing.kleros.io/smart-contract-workflow
* @authors: [@fnanni-0]
* @reviewers: [@shalzz, @unknownunknown1, @MerlinEgalite, @hbarcelos]
* @auditors: []
* @bounties: []
* @deployments: []
*/
/* solium-disable error-reason */
/* solium-disable security/no-block-members */
pragma solidity ^0.4.24;
/**
* @title xKlerosLiquid
* @dev This contract is an adaption of Mainnet's KlerosLiquid (https://github.com/kleros/kleros/blob/69cfbfb2128c29f1625b3a99a3183540772fda08/contracts/kleros/KlerosLiquid.sol)
* for xDai chain. Notice that variables referring to ETH values in this contract, will hold the native token values of the chain on which xKlerosLiquid is deployed.
* When this contract gets deployed on xDai chain, ETH variables will hold xDai values.
*/
contract xKlerosLiquid is Initializable, TokenController, Arbitrator {
/* Enums */
// General
enum Phase {
staking, // Stake sum trees can be updated. Pass after `minStakingTime` passes and there is at least one dispute without jurors.
generating, // Waiting for a random number. Pass as soon as it is ready.
drawing // Jurors can be drawn. Pass after all disputes have jurors or `maxDrawingTime` passes.
}
// Dispute
enum Period {
evidence, // Evidence can be submitted. This is also when drawing has to take place.
commit, // Jurors commit a hashed vote. This is skipped for courts without hidden votes.
vote, // Jurors reveal/cast their vote depending on whether the court has hidden votes or not.
appeal, // The dispute can be appealed.
execution // Tokens are redistributed and the ruling is executed.
}
/* Structs */
// General
struct Court {
uint96 parent; // The parent court.
uint[] children; // List of child courts.
bool hiddenVotes; // Whether to use commit and reveal or not.
uint minStake; // Minimum tokens needed to stake in the court.
uint alpha; // Basis point of tokens that are lost when incoherent.
uint feeForJuror; // Arbitration fee paid per juror.
// The appeal after the one that reaches this number of jurors will go to the parent court if any, otherwise, no more appeals are possible.
uint jurorsForCourtJump;
uint[4] timesPerPeriod; // The time allotted to each dispute period in the form `timesPerPeriod[period]`.
}
struct DelayedSetStake {
address account; // The address of the juror.
uint96 subcourtID; // The ID of the subcourt.
uint128 stake; // The new stake.
}
// Dispute
struct Vote {
address account; // The address of the juror.
bytes32 commit; // The commit of the juror. For courts with hidden votes.
uint choice; // The choice of the juror.
bool voted; // True if the vote has been cast or revealed, false otherwise.
}
struct VoteCounter {
// The choice with the most votes. Note that in the case of a tie, it is the choice that reached the tied number of votes first.
uint winningChoice;
mapping(uint => uint) counts; // The sum of votes for each choice in the form `counts[choice]`.
bool tied; // True if there is a tie, false otherwise.
}
struct Dispute { // Note that appeal `0` is equivalent to the first round of the dispute.
uint96 subcourtID; // The ID of the subcourt the dispute is in.
Arbitrable arbitrated; // The arbitrated arbitrable contract.
// The number of choices jurors have when voting. This does not include choice `0` which is reserved for "refuse to arbitrate"/"no ruling".
uint numberOfChoices;
Period period; // The current period of the dispute.
uint lastPeriodChange; // The last time the period was changed.
// The votes in the form `votes[appeal][voteID]`. On each round, a new list is pushed and packed with as many empty votes as there are draws. We use `dispute.votes.length` to get the number of appeals plus 1 for the first round.
Vote[][] votes;
VoteCounter[] voteCounters; // The vote counters in the form `voteCounters[appeal]`.
uint[] tokensAtStakePerJuror; // The amount of tokens at stake for each juror in the form `tokensAtStakePerJuror[appeal]`.
uint[] totalFeesForJurors; // The total juror fees paid in the form `totalFeesForJurors[appeal]`.
uint drawsInRound; // A counter of draws made in the current round.
uint commitsInRound; // A counter of commits made in the current round.
uint[] votesInEachRound; // A counter of votes made in each round in the form `votesInEachRound[appeal]`.
// A counter of vote reward repartitions made in each round in the form `repartitionsInEachRound[appeal]`.
uint[] repartitionsInEachRound;
uint[] penaltiesInEachRound; // The amount of tokens collected from penalties in each round in the form `penaltiesInEachRound[appeal]`.
bool ruled; // True if the ruling has been executed, false otherwise.
}
// Juror
struct Juror {
// The IDs of subcourts where the juror has stake path ends. A stake path is a path from the general court to a court the juror directly staked in using `_setStake`.
uint96[] subcourtIDs;
uint stakedTokens; // The juror's total amount of tokens staked in subcourts.
uint lockedTokens; // The juror's total amount of tokens locked in disputes.
}
/* Events */
/** @dev Emitted when we pass to a new phase.
* @param _phase The new phase.
*/
event NewPhase(Phase _phase);
/** @dev Emitted when a dispute passes to a new period.
* @param _disputeID The ID of the dispute.
* @param _period The new period.
*/
event NewPeriod(uint indexed _disputeID, Period _period);
/** @dev Emitted when a juror's stake is set.
* @param _address The address of the juror.
* @param _subcourtID The ID of the subcourt at the end of the stake path.
* @param _stake The new stake.
* @param _newTotalStake The new total stake.
*/
event StakeSet(address indexed _address, uint _subcourtID, uint128 _stake, uint _newTotalStake);
/** @dev Emitted when a juror is drawn.
* @param _address The drawn address.
* @param _disputeID The ID of the dispute.
* @param _appeal The appeal the draw is for. 0 is for the first round.
* @param _voteID The vote ID.
*/
event Draw(address indexed _address, uint indexed _disputeID, uint _appeal, uint _voteID);
/** @dev Emitted when a juror wins or loses tokens and ETH from a dispute.
* @param _address The juror affected.
* @param _disputeID The ID of the dispute.
* @param _tokenAmount The amount of tokens won or lost.
* @param _ETHAmount The amount of ETH won or lost.
*/
event TokenAndETHShift(address indexed _address, uint indexed _disputeID, int _tokenAmount, int _ETHAmount);
/* Storage */
// General Constants
uint public constant MAX_STAKE_PATHS = 4; // The maximum number of stake paths a juror can have.
uint public constant MIN_JURORS = 3; // The global default minimum number of jurors in a dispute.
uint public constant NON_PAYABLE_AMOUNT = (2 ** 256 - 2) / 2; // An amount higher than the supply of ETH.
uint public constant ALPHA_DIVISOR = 1e4; // The number to divide `Court.alpha` by.
// General Contracts
address public governor; // The governor of the contract.
WrappedPinakion public pinakion; // The Pinakion token contract.
IRandomAuRa public RNGenerator; // The random number generator contract.
// General Dynamic
Phase public phase; // The current phase.
uint public lastPhaseChange; // The last time the phase was changed.
uint public disputesWithoutJurors; // The number of disputes that have not finished drawing jurors.
// The block number to get the next random number from. Used so there is at least a 1 block difference from the staking phase.
uint public RNBlock;
uint public RN; // The current random number.
uint public minStakingTime; // The minimum staking time.
uint public maxDrawingTime; // The maximum drawing time.
// True if insolvent (`balance < stakedTokens || balance < lockedTokens`) token transfers should be blocked. Used to avoid blocking penalties.
bool public lockInsolventTransfers;
// General Storage
Court[] public courts; // The subcourts.
using SortitionSumTreeFactory for SortitionSumTreeFactory.SortitionSumTrees; // Use library functions for sortition sum trees.
SortitionSumTreeFactory.SortitionSumTrees internal sortitionSumTrees; // The sortition sum trees.
// The delayed calls to `_setStake`. Used to schedule `_setStake`s when not in the staking phase.
mapping(uint => DelayedSetStake) public delayedSetStakes;
// The index of the next `delayedSetStakes` item to execute. Starts at 1 because `lastDelayedSetStake` starts at 0.
uint public nextDelayedSetStake;
uint public lastDelayedSetStake; // The index of the last `delayedSetStakes` item. 0 is skipped because it is the initial value.
// Dispute
// Use a mapping instead of an array so that upgrading (appending variables to) the Dispute struct is possible without big layout changes.
mapping(uint => Dispute) public disputes; // The disputes.
uint public totalDisputes;
// Juror
mapping(address => Juror) public jurors; // The jurors.
/* Modifiers */
/** @dev Requires a specific phase.
* @param _phase The required phase.
*/
modifier onlyDuringPhase(Phase _phase) {require(phase == _phase); _;}
/** @dev Requires a specific period in a dispute.
* @param _disputeID The ID of the dispute.
* @param _period The required period.
*/
modifier onlyDuringPeriod(uint _disputeID, Period _period) {require(disputes[_disputeID].period == _period); _;}
/** @dev Requires that the sender is the governor. Note that the governor is expected to not be malicious. */
modifier onlyByGovernor() {require(governor == msg.sender); _;}
/* Constructor */
/** @dev Constructs the KlerosLiquid contract.
* @param _governor The governor's address.
* @param _pinakion The address of the token contract.
* @param _RNGenerator The address of the random number generator contract.
* @param _minStakingTime The minimum time that the staking phase should last.
* @param _maxDrawingTime The maximum time that the drawing phase should last.
* @param _hiddenVotes The `hiddenVotes` property value of the general court.
* @param _minStake The `minStake` property value of the general court.
* @param _alpha The `alpha` property value of the general court.
* @param _feeForJuror The `feeForJuror` property value of the general court.
* @param _jurorsForCourtJump The `jurorsForCourtJump` property value of the general court.
* @param _timesPerPeriod The `timesPerPeriod` property value of the general court.
* @param _sortitionSumTreeK The number of children per node of the general court's sortition sum tree.
*/
function initialize(
address _governor,
WrappedPinakion _pinakion,
IRandomAuRa _RNGenerator,
uint _minStakingTime,
uint _maxDrawingTime,
bool _hiddenVotes,
uint _minStake,
uint _alpha,
uint _feeForJuror,
uint _jurorsForCourtJump,
uint[4] _timesPerPeriod,
uint _sortitionSumTreeK
) public initializer {
// Initialize contract.
governor = _governor;
pinakion = _pinakion;
RNGenerator = _RNGenerator;
minStakingTime = _minStakingTime;
maxDrawingTime = _maxDrawingTime;
lastPhaseChange = now;
lockInsolventTransfers = true;
nextDelayedSetStake = 1;
// Create the general court.
courts.push(Court({
parent: 0,
children: new uint[](0),
hiddenVotes: _hiddenVotes,
minStake: _minStake,
alpha: _alpha,
feeForJuror: _feeForJuror,
jurorsForCourtJump: _jurorsForCourtJump,
timesPerPeriod: _timesPerPeriod
}));
sortitionSumTrees.createTree(bytes32(0), _sortitionSumTreeK);
}
/* External */
/** @dev Lets the governor call anything on behalf of the contract.
* @param _destination The destination of the call.
* @param _amount The value sent with the call.
* @param _data The data sent with the call.
*/
function executeGovernorProposal(address _destination, uint _amount, bytes _data) external onlyByGovernor {
require(_destination.call.value(_amount)(_data)); // solium-disable-line security/no-call-value
}
/** @dev Changes the `governor` storage variable.
* @param _governor The new value for the `governor` storage variable.
*/
function changeGovernor(address _governor) external onlyByGovernor {
governor = _governor;
}
/** @dev Changes the `pinakion` storage variable.
* @param _pinakion The new value for the `pinakion` storage variable.
*/
function changePinakion(WrappedPinakion _pinakion) external onlyByGovernor {
pinakion = _pinakion;
}
/** @dev Changes the `RNGenerator` storage variable.
* @param _RNGenerator The new value for the `RNGenerator` storage variable.
*/
function changeRNGenerator(IRandomAuRa _RNGenerator) external onlyByGovernor {
RNGenerator = _RNGenerator;
if (phase == Phase.generating) {
RNBlock = RNGenerator.nextCommitPhaseStartBlock() + RNGenerator.collectRoundLength();
}
}
/** @dev Changes the `minStakingTime` storage variable.
* @param _minStakingTime The new value for the `minStakingTime` storage variable.
*/
function changeMinStakingTime(uint _minStakingTime) external onlyByGovernor {
minStakingTime = _minStakingTime;
}
/** @dev Changes the `maxDrawingTime` storage variable.
* @param _maxDrawingTime The new value for the `maxDrawingTime` storage variable.
*/
function changeMaxDrawingTime(uint _maxDrawingTime) external onlyByGovernor {
maxDrawingTime = _maxDrawingTime;
}
/** @dev Creates a subcourt under a specified parent court.
* @param _parent The `parent` property value of the subcourt.
* @param _hiddenVotes The `hiddenVotes` property value of the subcourt.
* @param _minStake The `minStake` property value of the subcourt.
* @param _alpha The `alpha` property value of the subcourt.
* @param _feeForJuror The `feeForJuror` property value of the subcourt.
* @param _jurorsForCourtJump The `jurorsForCourtJump` property value of the subcourt.
* @param _timesPerPeriod The `timesPerPeriod` property value of the subcourt.
* @param _sortitionSumTreeK The number of children per node of the subcourt's sortition sum tree.
*/
function createSubcourt(
uint96 _parent,
bool _hiddenVotes,
uint _minStake,
uint _alpha,
uint _feeForJuror,
uint _jurorsForCourtJump,
uint[4] _timesPerPeriod,
uint _sortitionSumTreeK
) external onlyByGovernor {
require(courts[_parent].minStake <= _minStake, "A subcourt cannot be a child of a subcourt with a higher minimum stake.");
// Create the subcourt.
uint96 subcourtID = uint96(
courts.push(Court({
parent: _parent,
children: new uint[](0),
hiddenVotes: _hiddenVotes,
minStake: _minStake,
alpha: _alpha,
feeForJuror: _feeForJuror,
jurorsForCourtJump: _jurorsForCourtJump,
timesPerPeriod: _timesPerPeriod
})) - 1
);
sortitionSumTrees.createTree(bytes32(subcourtID), _sortitionSumTreeK);
// Update the parent.
courts[_parent].children.push(subcourtID);
}
/** @dev Changes the `minStake` property value of a specified subcourt. Don't set to a value lower than its parent's `minStake` property value.
* @param _subcourtID The ID of the subcourt.
* @param _minStake The new value for the `minStake` property value.
*/
function changeSubcourtMinStake(uint96 _subcourtID, uint _minStake) external onlyByGovernor {
require(_subcourtID == 0 || courts[courts[_subcourtID].parent].minStake <= _minStake);
for (uint i = 0; i < courts[_subcourtID].children.length; i++) {
require(
courts[courts[_subcourtID].children[i]].minStake >= _minStake,
"A subcourt cannot be the parent of a subcourt with a lower minimum stake."
);
}
courts[_subcourtID].minStake = _minStake;
}
/** @dev Changes the `alpha` property value of a specified subcourt.
* @param _subcourtID The ID of the subcourt.
* @param _alpha The new value for the `alpha` property value.
*/
function changeSubcourtAlpha(uint96 _subcourtID, uint _alpha) external onlyByGovernor {
courts[_subcourtID].alpha = _alpha;
}
/** @dev Changes the `feeForJuror` property value of a specified subcourt.
* @param _subcourtID The ID of the subcourt.
* @param _feeForJuror The new value for the `feeForJuror` property value.
*/
function changeSubcourtJurorFee(uint96 _subcourtID, uint _feeForJuror) external onlyByGovernor {
courts[_subcourtID].feeForJuror = _feeForJuror;
}
/** @dev Changes the `jurorsForCourtJump` property value of a specified subcourt.
* @param _subcourtID The ID of the subcourt.
* @param _jurorsForCourtJump The new value for the `jurorsForCourtJump` property value.
*/
function changeSubcourtJurorsForJump(uint96 _subcourtID, uint _jurorsForCourtJump) external onlyByGovernor {
courts[_subcourtID].jurorsForCourtJump = _jurorsForCourtJump;
}
/** @dev Changes the `timesPerPeriod` property value of a specified subcourt.
* @param _subcourtID The ID of the subcourt.
* @param _timesPerPeriod The new value for the `timesPerPeriod` property value.
*/
function changeSubcourtTimesPerPeriod(uint96 _subcourtID, uint[4] _timesPerPeriod) external onlyByGovernor {
courts[_subcourtID].timesPerPeriod = _timesPerPeriod;
}
/** @dev Passes the phase. TRUSTED */
function passPhase() external {
if (phase == Phase.staking) {
require(now - lastPhaseChange >= minStakingTime, "The minimum staking time has not passed yet.");
require(disputesWithoutJurors > 0, "There are no disputes that need jurors.");
/** collectRoundLength is added so that the last validator to reveal cannot know
* during the staking phase which random seed is going to be used in the drawing phase.
*/
RNBlock = RNGenerator.nextCommitPhaseStartBlock() + RNGenerator.collectRoundLength();
phase = Phase.generating;
} else if (phase == Phase.generating) {
require(block.number >= RNBlock && RNGenerator.isCommitPhase(), "Random number is not ready yet."); // It's not secure to use the current seed during reveals.
RN = uint(keccak256(abi.encodePacked(address(this), RNGenerator.currentSeed()))); // currentSeed() cannot be predicted during staking phase.
phase = Phase.drawing;
} else if (phase == Phase.drawing) {
require(disputesWithoutJurors == 0 || now - lastPhaseChange >= maxDrawingTime, "There are still disputes without jurors and the maximum drawing time has not passed yet.");
phase = Phase.staking;
}
lastPhaseChange = now;
emit NewPhase(phase);
}
/** @dev Passes the period of a specified dispute.
* @param _disputeID The ID of the dispute.
*/
function passPeriod(uint _disputeID) external {
require(_disputeID < totalDisputes, "Dispute ID does not exist.");
Dispute storage dispute = disputes[_disputeID];
if (dispute.period == Period.evidence) {
require(
dispute.votes.length > 1 || now - dispute.lastPeriodChange >= courts[dispute.subcourtID].timesPerPeriod[uint(dispute.period)],
"The evidence period time has not passed yet and it is not an appeal."
);
require(dispute.drawsInRound == dispute.votes[dispute.votes.length - 1].length, "The dispute has not finished drawing yet.");
dispute.period = courts[dispute.subcourtID].hiddenVotes ? Period.commit : Period.vote;
} else if (dispute.period == Period.commit) {
require(
now - dispute.lastPeriodChange >= courts[dispute.subcourtID].timesPerPeriod[uint(dispute.period)] || dispute.commitsInRound == dispute.votes[dispute.votes.length - 1].length,
"The commit period time has not passed yet and not every juror has committed yet."
);
dispute.period = Period.vote;
} else if (dispute.period == Period.vote) {
require(
now - dispute.lastPeriodChange >= courts[dispute.subcourtID].timesPerPeriod[uint(dispute.period)] || dispute.votesInEachRound[dispute.votes.length - 1] == dispute.votes[dispute.votes.length - 1].length,
"The vote period time has not passed yet and not every juror has voted yet."
);
dispute.period = Period.appeal;
emit AppealPossible(_disputeID, dispute.arbitrated);
} else if (dispute.period == Period.appeal) {
require(now - dispute.lastPeriodChange >= courts[dispute.subcourtID].timesPerPeriod[uint(dispute.period)], "The appeal period time has not passed yet.");
dispute.period = Period.execution;
} else if (dispute.period == Period.execution) {
revert("The dispute is already in the last period.");
}
dispute.lastPeriodChange = now;
emit NewPeriod(_disputeID, dispute.period);
}
/** @dev Sets the caller's stake in a subcourt.
* @param _subcourtID The ID of the subcourt.
* @param _stake The new stake.
*/
function setStake(uint96 _subcourtID, uint128 _stake) external {
require(_setStake(msg.sender, _subcourtID, _stake));
}
/** @dev Executes the next delayed set stakes.
* `O(n)` where `n` is the number of iterations to run.
* @param _iterations The number of delayed set stakes to execute.
*/
function executeDelayedSetStakes(uint _iterations) external onlyDuringPhase(Phase.staking) {
uint actualIterations = (nextDelayedSetStake + _iterations) - 1 > lastDelayedSetStake ?
(lastDelayedSetStake - nextDelayedSetStake) + 1 : _iterations;
uint newNextDelayedSetStake = nextDelayedSetStake + actualIterations;
require(newNextDelayedSetStake >= nextDelayedSetStake);
for (uint i = nextDelayedSetStake; i < newNextDelayedSetStake; i++) {
DelayedSetStake storage delayedSetStake = delayedSetStakes[i];
_setStake(delayedSetStake.account, delayedSetStake.subcourtID, delayedSetStake.stake);
delete delayedSetStakes[i];
}
nextDelayedSetStake = newNextDelayedSetStake;
}
/** @dev Draws jurors for a dispute. Can be called in parts.
* `O(n * k * log_k(j))` where
* `n` is the number of iterations to run,
* `k` is the number of children per node of the dispute's court's sortition sum tree,
* and `j` is the maximum number of jurors that ever staked in it simultaneously.
* @param _disputeID The ID of the dispute.
* @param _iterations The number of iterations to run.
*/
function drawJurors(
uint _disputeID,
uint _iterations
) external onlyDuringPhase(Phase.drawing) onlyDuringPeriod(_disputeID, Period.evidence) {
require(_disputeID < totalDisputes, "Dispute ID does not exist.");
Dispute storage dispute = disputes[_disputeID];
uint endIndex = dispute.drawsInRound + _iterations;
require(endIndex >= dispute.drawsInRound);
// Avoid going out of range.
if (endIndex > dispute.votes[dispute.votes.length - 1].length) endIndex = dispute.votes[dispute.votes.length - 1].length;
for (uint i = dispute.drawsInRound; i < endIndex; i++) {
// Draw from sortition tree.
(
address drawnAddress,
uint subcourtID
) = stakePathIDToAccountAndSubcourtID(sortitionSumTrees.draw(bytes32(dispute.subcourtID), uint(keccak256(RN, _disputeID, i))));
// Save the vote.
dispute.votes[dispute.votes.length - 1][i].account = drawnAddress;
jurors[drawnAddress].lockedTokens += dispute.tokensAtStakePerJuror[dispute.tokensAtStakePerJuror.length - 1];
emit Draw(drawnAddress, _disputeID, dispute.votes.length - 1, i);
// If dispute is fully drawn.
if (i == dispute.votes[dispute.votes.length - 1].length - 1) disputesWithoutJurors--;
}
dispute.drawsInRound = endIndex;
}
/** @dev Sets the caller's commit for the specified votes.
* `O(n)` where
* `n` is the number of votes.
* @param _disputeID The ID of the dispute.
* @param _voteIDs The IDs of the votes.
* @param _commit The commit.
*/
function castCommit(uint _disputeID, uint[] _voteIDs, bytes32 _commit) external onlyDuringPeriod(_disputeID, Period.commit) {
Dispute storage dispute = disputes[_disputeID];
require(_commit != bytes32(0));
for (uint i = 0; i < _voteIDs.length; i++) {
require(dispute.votes[dispute.votes.length - 1][_voteIDs[i]].account == msg.sender, "The caller has to own the vote.");
require(dispute.votes[dispute.votes.length - 1][_voteIDs[i]].commit == bytes32(0), "Already committed this vote.");
dispute.votes[dispute.votes.length - 1][_voteIDs[i]].commit = _commit;
}
dispute.commitsInRound += _voteIDs.length;
}
/** @dev Sets the caller's choices for the specified votes.
* `O(n)` where
* `n` is the number of votes.
* @param _disputeID The ID of the dispute.
* @param _voteIDs The IDs of the votes.
* @param _choice The choice.
* @param _salt The salt for the commit if the votes were hidden.
*/
function castVote(uint _disputeID, uint[] _voteIDs, uint _choice, uint _salt) external onlyDuringPeriod(_disputeID, Period.vote) {
Dispute storage dispute = disputes[_disputeID];
require(_voteIDs.length > 0);
require(_choice <= dispute.numberOfChoices, "The choice has to be less than or equal to the number of choices for the dispute.");
// Save the votes.
for (uint i = 0; i < _voteIDs.length; i++) {
require(dispute.votes[dispute.votes.length - 1][_voteIDs[i]].account == msg.sender, "The caller has to own the vote.");
require(
!courts[dispute.subcourtID].hiddenVotes || dispute.votes[dispute.votes.length - 1][_voteIDs[i]].commit == keccak256(_choice, _salt),
"The commit must match the choice in subcourts with hidden votes."
);
require(!dispute.votes[dispute.votes.length - 1][_voteIDs[i]].voted, "Vote already cast.");
dispute.votes[dispute.votes.length - 1][_voteIDs[i]].choice = _choice;
dispute.votes[dispute.votes.length - 1][_voteIDs[i]].voted = true;
}
dispute.votesInEachRound[dispute.votes.length - 1] += _voteIDs.length;
// Update winning choice.
VoteCounter storage voteCounter = dispute.voteCounters[dispute.voteCounters.length - 1];
voteCounter.counts[_choice] += _voteIDs.length;
if (_choice == voteCounter.winningChoice) { // Voted for the winning choice.
if (voteCounter.tied) voteCounter.tied = false; // Potentially broke tie.
} else { // Voted for another choice.
if (voteCounter.counts[_choice] == voteCounter.counts[voteCounter.winningChoice]) { // Tie.
if (!voteCounter.tied) voteCounter.tied = true;
} else if (voteCounter.counts[_choice] > voteCounter.counts[voteCounter.winningChoice]) { // New winner.
voteCounter.winningChoice = _choice;
voteCounter.tied = false;
}
}
}
/** @dev Computes the token and ETH rewards for a specified appeal in a specified dispute.
* @param _disputeID The ID of the dispute.
* @param _appeal The appeal.
* @return tokenReward The token reward.
* @return ETHReward The ETH reward.
*/
function computeTokenAndETHRewards(uint _disputeID, uint _appeal) private view returns(uint tokenReward, uint ETHReward) {
Dispute storage dispute = disputes[_disputeID];
// Distribute penalties and arbitration fees.
if (dispute.voteCounters[dispute.voteCounters.length - 1].tied) {
// Distribute penalties and fees evenly between active jurors.
uint activeCount = dispute.votesInEachRound[_appeal];
if (activeCount > 0) {
tokenReward = dispute.penaltiesInEachRound[_appeal] / activeCount;
ETHReward = dispute.totalFeesForJurors[_appeal] / activeCount;
} else {
tokenReward = 0;
ETHReward = 0;
}
} else {
// Distribute penalties and fees evenly between coherent jurors.
uint winningChoice = dispute.voteCounters[dispute.voteCounters.length - 1].winningChoice;
uint coherentCount = dispute.voteCounters[_appeal].counts[winningChoice];
tokenReward = dispute.penaltiesInEachRound[_appeal] / coherentCount;
ETHReward = dispute.totalFeesForJurors[_appeal] / coherentCount;
}
}
/** @dev Repartitions tokens and ETH for a specified appeal in a specified dispute. Can be called in parts.
* `O(i + u * n * (n + p * log_k(j)))` where
* `i` is the number of iterations to run,
* `u` is the number of jurors that need to be unstaked,
* `n` is the maximum number of subcourts one of these jurors has staked in,
* `p` is the depth of the subcourt tree,
* `k` is the minimum number of children per node of one of these subcourts' sortition sum tree,
* and `j` is the maximum number of jurors that ever staked in one of these subcourts simultaneously.
* @param _disputeID The ID of the dispute.
* @param _appeal The appeal.
* @param _iterations The number of iterations to run.
*/
function execute(uint _disputeID, uint _appeal, uint _iterations) external onlyDuringPeriod(_disputeID, Period.execution) {
lockInsolventTransfers = false;
Dispute storage dispute = disputes[_disputeID];
uint end = dispute.repartitionsInEachRound[_appeal] + _iterations;
require(end >= dispute.repartitionsInEachRound[_appeal]);
uint penaltiesInRoundCache = dispute.penaltiesInEachRound[_appeal]; // For saving gas.
(uint tokenReward, uint ETHReward) = (0, 0);
// Avoid going out of range.
if (
!dispute.voteCounters[dispute.voteCounters.length - 1].tied &&
dispute.voteCounters[_appeal].counts[dispute.voteCounters[dispute.voteCounters.length - 1].winningChoice] == 0
) {
// We loop over the votes once as there are no rewards because it is not a tie and no one in this round is coherent with the final outcome.
if (end > dispute.votes[_appeal].length) end = dispute.votes[_appeal].length;
} else {
// We loop over the votes twice, first to collect penalties, and second to distribute them as rewards along with arbitration fees.
(tokenReward, ETHReward) = dispute.repartitionsInEachRound[_appeal] >= dispute.votes[_appeal].length ? computeTokenAndETHRewards(_disputeID, _appeal) : (0, 0); // Compute rewards if rewarding.
if (end > dispute.votes[_appeal].length * 2) end = dispute.votes[_appeal].length * 2;
}
for (uint i = dispute.repartitionsInEachRound[_appeal]; i < end; i++) {
Vote storage vote = dispute.votes[_appeal][i % dispute.votes[_appeal].length];
if (
vote.voted &&
(vote.choice == dispute.voteCounters[dispute.voteCounters.length - 1].winningChoice || dispute.voteCounters[dispute.voteCounters.length - 1].tied)
) { // Juror was active, and voted coherently or it was a tie.
if (i >= dispute.votes[_appeal].length) { // Only execute in the second half of the iterations.
// Reward.
pinakion.transfer(vote.account, tokenReward);
// Intentional use to avoid blocking.
vote.account.send(ETHReward); // solium-disable-line security/no-send
emit TokenAndETHShift(vote.account, _disputeID, int(tokenReward), int(ETHReward));
jurors[vote.account].lockedTokens -= dispute.tokensAtStakePerJuror[_appeal];
}
} else { // Juror was inactive, or voted incoherently and it was not a tie.
if (i < dispute.votes[_appeal].length) { // Only execute in the first half of the iterations.
// Penalize.
uint penalty = dispute.tokensAtStakePerJuror[_appeal] > pinakion.balanceOf(vote.account) ? pinakion.balanceOf(vote.account) : dispute.tokensAtStakePerJuror[_appeal];
pinakion.transferFrom(vote.account, this, penalty);
emit TokenAndETHShift(vote.account, _disputeID, -int(penalty), 0);
penaltiesInRoundCache += penalty;
jurors[vote.account].lockedTokens -= dispute.tokensAtStakePerJuror[_appeal];
// Unstake juror if his penalty made balance less than his total stake or if he lost due to inactivity.
if (pinakion.balanceOf(vote.account) < jurors[vote.account].stakedTokens || !vote.voted)
for (uint j = 0; j < jurors[vote.account].subcourtIDs.length; j++)
_setStake(vote.account, jurors[vote.account].subcourtIDs[j], 0);
}
}
if (i == dispute.votes[_appeal].length - 1) {
// Send fees and tokens to the governor if no one was coherent.
if (dispute.votesInEachRound[_appeal] == 0 || !dispute.voteCounters[dispute.voteCounters.length - 1].tied && dispute.voteCounters[_appeal].counts[dispute.voteCounters[dispute.voteCounters.length - 1].winningChoice] == 0) {
// Intentional use to avoid blocking.
governor.send(dispute.totalFeesForJurors[_appeal]); // solium-disable-line security/no-send
pinakion.transfer(governor, penaltiesInRoundCache);
} else if (i + 1 < end) {
// Compute rewards because we are going into rewarding.
dispute.penaltiesInEachRound[_appeal] = penaltiesInRoundCache;
(tokenReward, ETHReward) = computeTokenAndETHRewards(_disputeID, _appeal);
}
}
}
if (dispute.penaltiesInEachRound[_appeal] != penaltiesInRoundCache) dispute.penaltiesInEachRound[_appeal] = penaltiesInRoundCache;
dispute.repartitionsInEachRound[_appeal] = end;
lockInsolventTransfers = true;
}
/** @dev Executes a specified dispute's ruling. UNTRUSTED.
* @param _disputeID The ID of the dispute.
*/
function executeRuling(uint _disputeID) external onlyDuringPeriod(_disputeID, Period.execution) {
Dispute storage dispute = disputes[_disputeID];
require(!dispute.ruled, "Ruling already executed.");
dispute.ruled = true;
uint winningChoice = dispute.voteCounters[dispute.voteCounters.length - 1].tied ? 0
: dispute.voteCounters[dispute.voteCounters.length - 1].winningChoice;
dispute.arbitrated.rule(_disputeID, winningChoice);
}
/* Public */
/** @dev Creates a dispute. Must be called by the arbitrable contract.
* @param _numberOfChoices Number of choices to choose from in the dispute to be created.
* @param _extraData Additional info about the dispute to be created. We use it to pass the ID of the subcourt to create the dispute in (first 32 bytes) and the minimum number of jurors required (next 32 bytes).
* @return disputeID The ID of the created dispute.
*/
function createDispute(
uint _numberOfChoices,
bytes _extraData
) public payable requireArbitrationFee(_extraData) returns(uint disputeID) {
(uint96 subcourtID, uint minJurors) = extraDataToSubcourtIDAndMinJurors(_extraData);
disputeID = totalDisputes++;
Dispute storage dispute = disputes[disputeID];
dispute.subcourtID = subcourtID;
dispute.arbitrated = Arbitrable(msg.sender);
dispute.numberOfChoices = _numberOfChoices;
dispute.period = Period.evidence;
dispute.lastPeriodChange = now;
// As many votes that can be afforded by the provided funds.
dispute.votes[dispute.votes.length++].length = msg.value / courts[dispute.subcourtID].feeForJuror;
dispute.voteCounters[dispute.voteCounters.length++].tied = true;
dispute.tokensAtStakePerJuror.push((courts[dispute.subcourtID].minStake * courts[dispute.subcourtID].alpha) / ALPHA_DIVISOR);
dispute.totalFeesForJurors.push(msg.value);
dispute.votesInEachRound.push(0);
dispute.repartitionsInEachRound.push(0);
dispute.penaltiesInEachRound.push(0);
disputesWithoutJurors++;
emit DisputeCreation(disputeID, Arbitrable(msg.sender));
}
/** @dev Appeals the ruling of a specified dispute.
* @param _disputeID The ID of the dispute.
* @param _extraData Additional info about the appeal. Not used by this contract.
*/
function appeal(
uint _disputeID,
bytes _extraData
) public payable requireAppealFee(_disputeID, _extraData) onlyDuringPeriod(_disputeID, Period.appeal) {
Dispute storage dispute = disputes[_disputeID];
require(
msg.sender == address(dispute.arbitrated),
"Can only be called by the arbitrable contract."
);
if (dispute.votes[dispute.votes.length - 1].length >= courts[dispute.subcourtID].jurorsForCourtJump) // Jump to parent subcourt.
dispute.subcourtID = courts[dispute.subcourtID].parent;
dispute.period = Period.evidence;
dispute.lastPeriodChange = now;
// As many votes that can be afforded by the provided funds.
dispute.votes[dispute.votes.length++].length = msg.value / courts[dispute.subcourtID].feeForJuror;
dispute.voteCounters[dispute.voteCounters.length++].tied = true;
dispute.tokensAtStakePerJuror.push((courts[dispute.subcourtID].minStake * courts[dispute.subcourtID].alpha) / ALPHA_DIVISOR);
dispute.totalFeesForJurors.push(msg.value);
dispute.drawsInRound = 0;
dispute.commitsInRound = 0;
dispute.votesInEachRound.push(0);
dispute.repartitionsInEachRound.push(0);
dispute.penaltiesInEachRound.push(0);
disputesWithoutJurors++;
emit AppealDecision(_disputeID, Arbitrable(msg.sender));
emit NewPeriod(_disputeID, Period.evidence);
}
/** @dev DEPRECATED. Called when `_owner` sends ETH to the Wrapped Token contract.
* @param _owner The address that sent the ETH to create tokens.
* @return allowed Whether the operation should be allowed or not.
*/
function proxyPayment(address _owner) public payable returns(bool allowed) { allowed = false; }
/** @dev Notifies the controller about a token transfer allowing the controller to react if desired.
* @param _from The origin of the transfer.
* @param _to The destination of the transfer.
* @param _amount The amount of the transfer.
* @return allowed Whether the operation should be allowed or not.
*/
function onTransfer(address _from, address _to, uint _amount) public returns(bool allowed) {
if (lockInsolventTransfers) { // Never block penalties or rewards.
uint newBalance = pinakion.balanceOf(_from) - _amount;
if (newBalance < jurors[_from].stakedTokens || newBalance < jurors[_from].lockedTokens) return false;
}
allowed = true;
}
/** @dev Notifies the controller about an approval allowing the controller to react if desired.
* @param _owner The address that calls `approve()`.
* @param _spender The spender in the `approve()` call.
* @param _amount The amount in the `approve()` call.
* @return allowed Whether the operation should be allowed or not.
*/
function onApprove(address _owner, address _spender, uint _amount) public returns(bool allowed) { allowed = true; }
/* Public Views */
/** @dev Gets the cost of arbitration in a specified subcourt.
* @param _extraData Additional info about the dispute. We use it to pass the ID of the subcourt to create the dispute in (first 32 bytes) and the minimum number of jurors required (next 32 bytes).
* @return cost The cost.
*/
function arbitrationCost(bytes _extraData) public view returns(uint cost) {
(uint96 subcourtID, uint minJurors) = extraDataToSubcourtIDAndMinJurors(_extraData);
cost = courts[subcourtID].feeForJuror * minJurors;
}
/** @dev Gets the cost of appealing a specified dispute.
* @param _disputeID The ID of the dispute.
* @param _extraData Additional info about the appeal. Not used by this contract.
* @return cost The cost.
*/
function appealCost(uint _disputeID, bytes _extraData) public view returns(uint cost) {
Dispute storage dispute = disputes[_disputeID];
uint lastNumberOfJurors = dispute.votes[dispute.votes.length - 1].length;
if (lastNumberOfJurors >= courts[dispute.subcourtID].jurorsForCourtJump) { // Jump to parent subcourt.
if (dispute.subcourtID == 0) // Already in the general court.
cost = NON_PAYABLE_AMOUNT;
else // Get the cost of the parent subcourt.
cost = courts[courts[dispute.subcourtID].parent].feeForJuror * ((lastNumberOfJurors * 2) + 1);
} else // Stay in current subcourt.
cost = courts[dispute.subcourtID].feeForJuror * ((lastNumberOfJurors * 2) + 1);
}
/** @dev Gets the start and end of a specified dispute's current appeal period.
* @param _disputeID The ID of the dispute.
* @return start The start of the appeal period.
* @return end The end of the appeal period.
*/
function appealPeriod(uint _disputeID) public view returns(uint start, uint end) {
Dispute storage dispute = disputes[_disputeID];
if (dispute.period == Period.appeal) {
start = dispute.lastPeriodChange;
end = dispute.lastPeriodChange + courts[dispute.subcourtID].timesPerPeriod[uint(Period.appeal)];
} else {
start = 0;
end = 0;
}
}
/** @dev Gets the status of a specified dispute.
* @param _disputeID The ID of the dispute.
* @return status The status.
*/
function disputeStatus(uint _disputeID) public view returns(DisputeStatus status) {
Dispute storage dispute = disputes[_disputeID];
if (dispute.period < Period.appeal) status = DisputeStatus.Waiting;
else if (dispute.period < Period.execution) status = DisputeStatus.Appealable;
else status = DisputeStatus.Solved;
}
/** @dev Gets the current ruling of a specified dispute.
* @param _disputeID The ID of the dispute.
* @return ruling The current ruling.
*/
function currentRuling(uint _disputeID) public view returns(uint ruling) {
Dispute storage dispute = disputes[_disputeID];
ruling = dispute.voteCounters[dispute.voteCounters.length - 1].tied ? 0
: dispute.voteCounters[dispute.voteCounters.length - 1].winningChoice;
}
/* Internal */
/** @dev Sets the specified juror's stake in a subcourt.
* `O(n + p * log_k(j))` where
* `n` is the number of subcourts the juror has staked in,
* `p` is the depth of the subcourt tree,
* `k` is the minimum number of children per node of one of these subcourts' sortition sum tree,
* and `j` is the maximum number of jurors that ever staked in one of these subcourts simultaneously.
* @param _account The address of the juror.
* @param _subcourtID The ID of the subcourt.
* @param _stake The new stake.
* @return succeeded True if the call succeeded, false otherwise.
*/
function _setStake(address _account, uint96 _subcourtID, uint128 _stake) internal returns(bool succeeded) {
if (!(_subcourtID < courts.length))
return false;
// Delayed action logic.
if (phase != Phase.staking) {
delayedSetStakes[++lastDelayedSetStake] = DelayedSetStake({ account: _account, subcourtID: _subcourtID, stake: _stake });
return true;
}
if (!(_stake == 0 || courts[_subcourtID].minStake <= _stake))
return false; // The juror's stake cannot be lower than the minimum stake for the subcourt.
Juror storage juror = jurors[_account];
bytes32 stakePathID = accountAndSubcourtIDToStakePathID(_account, _subcourtID);
uint currentStake = sortitionSumTrees.stakeOf(bytes32(_subcourtID), stakePathID);
if (!(_stake == 0 || currentStake > 0 || juror.subcourtIDs.length < MAX_STAKE_PATHS))
return false; // Maximum stake paths reached.
uint newTotalStake = juror.stakedTokens - currentStake + _stake; // Can't overflow because _stake is a uint128.
if (!(_stake == 0 || pinakion.balanceOf(_account) >= newTotalStake))
return false; // The juror's total amount of staked tokens cannot be higher than the juror's balance.
// Update juror's records.
juror.stakedTokens = newTotalStake;
if (_stake == 0) {
for (uint i = 0; i < juror.subcourtIDs.length; i++)
if (juror.subcourtIDs[i] == _subcourtID) {
juror.subcourtIDs[i] = juror.subcourtIDs[juror.subcourtIDs.length - 1];
juror.subcourtIDs.length--;
break;
}
} else if (currentStake == 0) juror.subcourtIDs.push(_subcourtID);
// Update subcourt parents.
bool finished = false;
uint currentSubcourtID = _subcourtID;
while (!finished) {
sortitionSumTrees.set(bytes32(currentSubcourtID), _stake, stakePathID);
if (currentSubcourtID == 0) finished = true;
else currentSubcourtID = courts[currentSubcourtID].parent;
}
emit StakeSet(_account, _subcourtID, _stake, newTotalStake);
return true;
}
/** @dev Gets a subcourt ID and the minimum number of jurors required from a specified extra data bytes array.
* @param _extraData The extra data bytes array. The first 32 bytes are the subcourt ID and the next 32 bytes are the minimum number of jurors.
* @return subcourtID The subcourt ID.
* @return minJurors The minimum number of jurors required.
*/
function extraDataToSubcourtIDAndMinJurors(bytes _extraData) internal view returns (uint96 subcourtID, uint minJurors) {
if (_extraData.length >= 64) {
assembly { // solium-disable-line security/no-inline-assembly
subcourtID := mload(add(_extraData, 0x20))
minJurors := mload(add(_extraData, 0x40))
}
if (subcourtID >= courts.length) subcourtID = 0;
if (minJurors == 0) minJurors = MIN_JURORS;
} else {
subcourtID = 0;
minJurors = MIN_JURORS;
}
}
/** @dev Packs an account and a subcourt ID into a stake path ID.
* @param _account The account to pack.
* @param _subcourtID The subcourt ID to pack.
* @return stakePathID The stake path ID.
*/
function accountAndSubcourtIDToStakePathID(address _account, uint96 _subcourtID) internal pure returns (bytes32 stakePathID) {
assembly { // solium-disable-line security/no-inline-assembly
let ptr := mload(0x40)
for { let i := 0x00 } lt(i, 0x14) { i := add(i, 0x01) } {
mstore8(add(ptr, i), byte(add(0x0c, i), _account))
}
for { let i := 0x14 } lt(i, 0x20) { i := add(i, 0x01) } {
mstore8(add(ptr, i), byte(i, _subcourtID))
}
stakePathID := mload(ptr)
}
}
/** @dev Unpacks a stake path ID into an account and a subcourt ID.
* @param _stakePathID The stake path ID to unpack.
* @return account The account.
* @return subcourtID The subcourt ID.
*/
function stakePathIDToAccountAndSubcourtID(bytes32 _stakePathID) internal pure returns (address account, uint96 subcourtID) {
assembly { // solium-disable-line security/no-inline-assembly
let ptr := mload(0x40)
for { let i := 0x00 } lt(i, 0x14) { i := add(i, 0x01) } {
mstore8(add(add(ptr, 0x0c), i), byte(i, _stakePathID))
}
account := mload(ptr)
subcourtID := _stakePathID
}
}
/* Interface Views */
/** @dev Gets a specified subcourt's non primitive properties.
* @param _subcourtID The ID of the subcourt.
* @return children The subcourt's child court list.
* @return timesPerPeriod The subcourt's time per period.
*/
function getSubcourt(uint96 _subcourtID) external view returns(
uint[] children,
uint[4] timesPerPeriod
) {
Court storage subcourt = courts[_subcourtID];
children = subcourt.children;
timesPerPeriod = subcourt.timesPerPeriod;
}
/** @dev Gets a specified vote for a specified appeal in a specified dispute.
* @param _disputeID The ID of the dispute.
* @param _appeal The appeal.
* @param _voteID The ID of the vote.
* @return account The account for vote.
* @return commit The commit for vote.
* @return choice The choice for vote.
* @return voted True if the account voted, False otherwise.
*/
function getVote(uint _disputeID, uint _appeal, uint _voteID) external view returns(
address account,
bytes32 commit,
uint choice,
bool voted
) {
Vote storage vote = disputes[_disputeID].votes[_appeal][_voteID];
account = vote.account;
commit = vote.commit;
choice = vote.choice;
voted = vote.voted;
}
/** @dev Gets the vote counter for a specified appeal in a specified dispute.
* Note: This function is only to be used by the interface and it won't work if the number of choices is too high.
* @param _disputeID The ID of the dispute.
* @param _appeal The appeal.
* @return winningChoice The winning choice.
* @return counts The count.
* @return tied Whether the vote tied.
* `O(n)` where
* `n` is the number of choices of the dispute.
*/
function getVoteCounter(uint _disputeID, uint _appeal) external view returns(
uint winningChoice,
uint[] counts,
bool tied
) {
Dispute storage dispute = disputes[_disputeID];
VoteCounter storage voteCounter = dispute.voteCounters[_appeal];
winningChoice = voteCounter.winningChoice;
counts = new uint[](dispute.numberOfChoices + 1);
for (uint i = 0; i <= dispute.numberOfChoices; i++) counts[i] = voteCounter.counts[i];
tied = voteCounter.tied;
}
/** @dev Gets a specified dispute's non primitive properties.
* @param _disputeID The ID of the dispute.
* @return votesLengths The dispute's vote length.
* @return tokensAtStakePerJuror The dispute's required tokens at stake per Juror.
* @return totalFeesForJurors The dispute's total fees for Jurors.
* @return votesInEachRound The dispute's counter of votes made in each round.
* @return repartitionsInEachRound The dispute's counter of vote reward repartitions made in each round.
* @return penaltiesInEachRound The dispute's amount of tokens collected from penalties in each round.
* `O(a)` where
* `a` is the number of appeals of the dispute.
*/
function getDispute(uint _disputeID) external view returns(
uint[] votesLengths,
uint[] tokensAtStakePerJuror,
uint[] totalFeesForJurors,
uint[] votesInEachRound,
uint[] repartitionsInEachRound,
uint[] penaltiesInEachRound
) {
Dispute storage dispute = disputes[_disputeID];
votesLengths = new uint[](dispute.votes.length);
for (uint i = 0; i < dispute.votes.length; i++) votesLengths[i] = dispute.votes[i].length;
tokensAtStakePerJuror = dispute.tokensAtStakePerJuror;
totalFeesForJurors = dispute.totalFeesForJurors;
votesInEachRound = dispute.votesInEachRound;
repartitionsInEachRound = dispute.repartitionsInEachRound;
penaltiesInEachRound = dispute.penaltiesInEachRound;
}
/** @dev Gets a specified juror's non primitive properties.
* @param _account The address of the juror.
* @return subcourtIDs The juror's IDs of subcourts where the juror has stake path.
*/
function getJuror(address _account) external view returns(
uint96[] subcourtIDs
) {
Juror storage juror = jurors[_account];
subcourtIDs = juror.subcourtIDs;
}
/** @dev Gets the stake of a specified juror in a specified subcourt.
* @param _account The address of the juror.
* @param _subcourtID The ID of the subcourt.
* @return stake The stake.
*/
function stakeOf(address _account, uint96 _subcourtID) external view returns(uint stake) {
return sortitionSumTrees.stakeOf(bytes32(_subcourtID), accountAndSubcourtIDToStakePathID(_account, _subcourtID));
}
}Contract Security Audit
- No Contract Security Audit Submitted- Submit Audit Here
Contract ABI
API[{"constant":true,"inputs":[],"name":"klerosLiquid","outputs":[{"name":"","type":"address"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":true,"inputs":[{"name":"_account","type":"address"},{"name":"_subcourtID","type":"uint96"}],"name":"stakeOf","outputs":[{"name":"stake","type":"uint256"}],"payable":false,"stateMutability":"view","type":"function"},{"constant":true,"inputs":[{"name":"_account","type":"address"}],"name":"getJuror","outputs":[{"name":"subcourtIDs","type":"uint96[]"},{"name":"stakedTokens","type":"uint256"},{"name":"lockedTokens","type":"uint256"},{"name":"subcourtStakes","type":"uint256[]"}],"payable":false,"stateMutability":"view","type":"function"},{"inputs":[{"name":"_klerosLiquid","type":"address"}],"payable":false,"stateMutability":"nonpayable","type":"constructor"}]Contract Creation Code
608060405234801561001057600080fd5b50604051602080610cc8833981016040525160008054600160a060020a03909216600160a060020a0319909216919091179055610c76806100526000396000f30060806040526004361061003d5763ffffffff60e060020a6000350416636bb6cd868114610042578063a2473cc114610073578063d4155d1f146100b7575b600080fd5b34801561004e57600080fd5b5061005761017f565b60408051600160a060020a039092168252519081900360200190f35b34801561007f57600080fd5b506100a5600160a060020a03600435166bffffffffffffffffffffffff6024351661018e565b60408051918252519081900360200190f35b3480156100c357600080fd5b506100d8600160a060020a036004351661021c565b604051808060200185815260200184815260200180602001838103835287818151815260200191508051906020019060200280838360005b83811015610128578181015183820152602001610110565b50505050905001838103825284818151815260200191508051906020019060200280838360005b8381101561016757818101518382015260200161014f565b50505050905001965050505050505060405180910390f35b600054600160a060020a031681565b6000606080600061019e8661021c565b945050509250600090505b82518110156102135782818151811015156101c057fe5b906020019060200201516bffffffffffffffffffffffff16856001016bffffffffffffffffffffffff16141561020b5781818151811015156101fe57fe5b9060200190602002015193505b6001016101a9565b50505092915050565b60606000806060806000806000806000806000809054906101000a9004600160a060020a0316600160a060020a031663b4a616086040518163ffffffff1660e060020a028152600401602060405180830381600087803b15801561027f57600080fd5b505af1158015610293573d6000803e3d6000fd5b505050506040513d60208110156102a957600080fd5b50516040805182815260208084028201019091529080156102d4578160200160208202803883390190505b509a506000809054906101000a9004600160a060020a0316600160a060020a031663dca5f6b08d6040518263ffffffff1660e060020a0281526004018082600160a060020a0316600160a060020a031681526020019150506040805180830381600087803b15801561034557600080fd5b505af1158015610359573d6000803e3d6000fd5b505050506040513d604081101561036f57600080fd5b50805160209182015160008054604080517fb4a616080000000000000000000000000000000000000000000000000000000081529051949f50929d50600160a060020a03169363b4a6160893600480850194929391928390030190829087803b1580156103db57600080fd5b505af11580156103ef573d6000803e3d6000fd5b505050506040513d602081101561040557600080fd5b5051604080518281526020808402820101909152908015610430578160200160208202803883390190505b5097506000809054906101000a9004600160a060020a0316600160a060020a031663d4155d1f8d6040518263ffffffff1660e060020a0281526004018082600160a060020a0316600160a060020a03168152602001915050600060405180830381600087803b1580156104a257600080fd5b505af11580156104b6573d6000803e3d6000fd5b505050506040513d6000823e601f3d908101601f1916820160405260208110156104df57600080fd5b8101908080516401000000008111156104f757600080fd5b8201602081018481111561050a57600080fd5b815185602082028301116401000000008211171561052757600080fd5b50909a5060009950505050505b865186101561065657868681518110151561054b57fe5b906020019060200201516001018b8781518110151561056657fe5b6bffffffffffffffffffffffff9092166020928302909101909101526000548751600160a060020a039091169063a2473cc1908e908a908a9081106105a757fe5b60209081029091018101516040805160e060020a63ffffffff8716028152600160a060020a0390941660048501526bffffffffffffffffffffffff9091166024840152516044808401938290030181600087803b15801561060757600080fd5b505af115801561061b573d6000803e3d6000fd5b505050506040513d602081101561063157600080fd5b5051885189908890811061064157fe5b60209081029091010152600190950194610534565b6000809054906101000a9004600160a060020a0316600160a060020a031663c108f3b46040518163ffffffff1660e060020a028152600401602060405180830381600087803b1580156106a857600080fd5b505af11580156106bc573d6000803e3d6000fd5b505050506040513d60208110156106d257600080fd5b505195505b6000809054906101000a9004600160a060020a0316600160a060020a0316630d44cf796040518163ffffffff1660e060020a028152600401602060405180830381600087803b15801561072957600080fd5b505af115801561073d573d6000803e3d6000fd5b505050506040513d602081101561075357600080fd5b50518611610c3c5760008054604080517fb78a80ff000000000000000000000000000000000000000000000000000000008152600481018a90529051600160a060020a039092169263b78a80ff926024808401936060939083900390910190829087803b1580156107c357600080fd5b505af11580156107d7573d6000803e3d6000fd5b505050506040513d60608110156107ed57600080fd5b50805160208201516040909201519096509094509250600160a060020a038c81169086161415610c31576fffffffffffffffffffffffffffffffff831615156108d557600091505b8a518210156108d0578a8281518110151561084c57fe5b906020019060200201516bffffffffffffffffffffffff16846bffffffffffffffffffffffff1614156108c55760008b8381518110151561088957fe5b6bffffffffffffffffffffffff90921660209283029091019091015287516000908990849081106108b657fe5b602090810290910101526108d0565b600190910190610835565b610c31565b600091505b8a51600202821015610c31578a518210801561092b57508a828151811015156108ff57fe5b906020019060200201516bffffffffffffffffffffffff16846001016bffffffffffffffffffffffff16145b8061097357508a51821015801561097357508a8b518381151561094a57fe5b0681518110151561095757fe5b906020019060200201516bffffffffffffffffffffffff166000145b15610c26576000548b51600160a060020a0390911690631f5a0dd2908481151561099957fe5b066040518263ffffffff1660e060020a0281526004018082815260200191505060c060405180830381600087803b1580156109d357600080fd5b505af11580156109e7573d6000803e3d6000fd5b505050506040513d60c08110156109fd57600080fd5b506040015190506fffffffffffffffffffffffffffffffff83168111801590610b715750826fffffffffffffffffffffffffffffffff16888c5184811515610a4157fe5b06815181101515610a4e57fe5b906020019060200201518b03016000809054906101000a9004600160a060020a0316600160a060020a031663fbf405b06040518163ffffffff1660e060020a028152600401602060405180830381600087803b158015610aad57600080fd5b505af1158015610ac1573d6000803e3d6000fd5b505050506040513d6020811015610ad757600080fd5b8101908080519060200190929190505050600160a060020a03166370a082318e6040518263ffffffff1660e060020a0281526004018082600160a060020a0316600160a060020a03168152602001915050602060405180830381600087803b158015610b4257600080fd5b505af1158015610b56573d6000803e3d6000fd5b505050506040513d6020811015610b6c57600080fd5b505110155b15610c2657836001018b8c5184811515610b8757fe5b06815181101515610b9457fe5b6bffffffffffffffffffffffff9092166020928302909101909101528a516fffffffffffffffffffffffffffffffff841690899084811515610bd257fe5b06815181101515610bdf57fe5b906020019060200201518b03019950826fffffffffffffffffffffffffffffffff16888c5184811515610c0e57fe5b06815181101515610c1b57fe5b602090810290910101525b6001909101906108da565b6001909501946106d7565b5050505050505091935091935600a165627a7a7230582084f98f14ea9335a17d5b8b7bc26296be3555740150ef5e43505fff96e488cc3700290000000000000000000000009c1da9a04925bdfdedf0f6421bc7eea8305f9002
Deployed Bytecode
0x60806040526004361061003d5763ffffffff60e060020a6000350416636bb6cd868114610042578063a2473cc114610073578063d4155d1f146100b7575b600080fd5b34801561004e57600080fd5b5061005761017f565b60408051600160a060020a039092168252519081900360200190f35b34801561007f57600080fd5b506100a5600160a060020a03600435166bffffffffffffffffffffffff6024351661018e565b60408051918252519081900360200190f35b3480156100c357600080fd5b506100d8600160a060020a036004351661021c565b604051808060200185815260200184815260200180602001838103835287818151815260200191508051906020019060200280838360005b83811015610128578181015183820152602001610110565b50505050905001838103825284818151815260200191508051906020019060200280838360005b8381101561016757818101518382015260200161014f565b50505050905001965050505050505060405180910390f35b600054600160a060020a031681565b6000606080600061019e8661021c565b945050509250600090505b82518110156102135782818151811015156101c057fe5b906020019060200201516bffffffffffffffffffffffff16856001016bffffffffffffffffffffffff16141561020b5781818151811015156101fe57fe5b9060200190602002015193505b6001016101a9565b50505092915050565b60606000806060806000806000806000806000809054906101000a9004600160a060020a0316600160a060020a031663b4a616086040518163ffffffff1660e060020a028152600401602060405180830381600087803b15801561027f57600080fd5b505af1158015610293573d6000803e3d6000fd5b505050506040513d60208110156102a957600080fd5b50516040805182815260208084028201019091529080156102d4578160200160208202803883390190505b509a506000809054906101000a9004600160a060020a0316600160a060020a031663dca5f6b08d6040518263ffffffff1660e060020a0281526004018082600160a060020a0316600160a060020a031681526020019150506040805180830381600087803b15801561034557600080fd5b505af1158015610359573d6000803e3d6000fd5b505050506040513d604081101561036f57600080fd5b50805160209182015160008054604080517fb4a616080000000000000000000000000000000000000000000000000000000081529051949f50929d50600160a060020a03169363b4a6160893600480850194929391928390030190829087803b1580156103db57600080fd5b505af11580156103ef573d6000803e3d6000fd5b505050506040513d602081101561040557600080fd5b5051604080518281526020808402820101909152908015610430578160200160208202803883390190505b5097506000809054906101000a9004600160a060020a0316600160a060020a031663d4155d1f8d6040518263ffffffff1660e060020a0281526004018082600160a060020a0316600160a060020a03168152602001915050600060405180830381600087803b1580156104a257600080fd5b505af11580156104b6573d6000803e3d6000fd5b505050506040513d6000823e601f3d908101601f1916820160405260208110156104df57600080fd5b8101908080516401000000008111156104f757600080fd5b8201602081018481111561050a57600080fd5b815185602082028301116401000000008211171561052757600080fd5b50909a5060009950505050505b865186101561065657868681518110151561054b57fe5b906020019060200201516001018b8781518110151561056657fe5b6bffffffffffffffffffffffff9092166020928302909101909101526000548751600160a060020a039091169063a2473cc1908e908a908a9081106105a757fe5b60209081029091018101516040805160e060020a63ffffffff8716028152600160a060020a0390941660048501526bffffffffffffffffffffffff9091166024840152516044808401938290030181600087803b15801561060757600080fd5b505af115801561061b573d6000803e3d6000fd5b505050506040513d602081101561063157600080fd5b5051885189908890811061064157fe5b60209081029091010152600190950194610534565b6000809054906101000a9004600160a060020a0316600160a060020a031663c108f3b46040518163ffffffff1660e060020a028152600401602060405180830381600087803b1580156106a857600080fd5b505af11580156106bc573d6000803e3d6000fd5b505050506040513d60208110156106d257600080fd5b505195505b6000809054906101000a9004600160a060020a0316600160a060020a0316630d44cf796040518163ffffffff1660e060020a028152600401602060405180830381600087803b15801561072957600080fd5b505af115801561073d573d6000803e3d6000fd5b505050506040513d602081101561075357600080fd5b50518611610c3c5760008054604080517fb78a80ff000000000000000000000000000000000000000000000000000000008152600481018a90529051600160a060020a039092169263b78a80ff926024808401936060939083900390910190829087803b1580156107c357600080fd5b505af11580156107d7573d6000803e3d6000fd5b505050506040513d60608110156107ed57600080fd5b50805160208201516040909201519096509094509250600160a060020a038c81169086161415610c31576fffffffffffffffffffffffffffffffff831615156108d557600091505b8a518210156108d0578a8281518110151561084c57fe5b906020019060200201516bffffffffffffffffffffffff16846bffffffffffffffffffffffff1614156108c55760008b8381518110151561088957fe5b6bffffffffffffffffffffffff90921660209283029091019091015287516000908990849081106108b657fe5b602090810290910101526108d0565b600190910190610835565b610c31565b600091505b8a51600202821015610c31578a518210801561092b57508a828151811015156108ff57fe5b906020019060200201516bffffffffffffffffffffffff16846001016bffffffffffffffffffffffff16145b8061097357508a51821015801561097357508a8b518381151561094a57fe5b0681518110151561095757fe5b906020019060200201516bffffffffffffffffffffffff166000145b15610c26576000548b51600160a060020a0390911690631f5a0dd2908481151561099957fe5b066040518263ffffffff1660e060020a0281526004018082815260200191505060c060405180830381600087803b1580156109d357600080fd5b505af11580156109e7573d6000803e3d6000fd5b505050506040513d60c08110156109fd57600080fd5b506040015190506fffffffffffffffffffffffffffffffff83168111801590610b715750826fffffffffffffffffffffffffffffffff16888c5184811515610a4157fe5b06815181101515610a4e57fe5b906020019060200201518b03016000809054906101000a9004600160a060020a0316600160a060020a031663fbf405b06040518163ffffffff1660e060020a028152600401602060405180830381600087803b158015610aad57600080fd5b505af1158015610ac1573d6000803e3d6000fd5b505050506040513d6020811015610ad757600080fd5b8101908080519060200190929190505050600160a060020a03166370a082318e6040518263ffffffff1660e060020a0281526004018082600160a060020a0316600160a060020a03168152602001915050602060405180830381600087803b158015610b4257600080fd5b505af1158015610b56573d6000803e3d6000fd5b505050506040513d6020811015610b6c57600080fd5b505110155b15610c2657836001018b8c5184811515610b8757fe5b06815181101515610b9457fe5b6bffffffffffffffffffffffff9092166020928302909101909101528a516fffffffffffffffffffffffffffffffff841690899084811515610bd257fe5b06815181101515610bdf57fe5b906020019060200201518b03019950826fffffffffffffffffffffffffffffffff16888c5184811515610c0e57fe5b06815181101515610c1b57fe5b602090810290910101525b6001909101906108da565b6001909501946106d7565b5050505050505091935091935600a165627a7a7230582084f98f14ea9335a17d5b8b7bc26296be3555740150ef5e43505fff96e488cc370029
Constructor Arguments (ABI-Encoded and is the last bytes of the Contract Creation Code above)
0000000000000000000000009c1da9a04925bdfdedf0f6421bc7eea8305f9002
-----Decoded View---------------
Arg [0] : _klerosLiquid (address): 0x9C1dA9A04925bDfDedf0f6421bC7EEa8305F9002
-----Encoded View---------------
1 Constructor Arguments found :
Arg [0] : 0000000000000000000000009c1da9a04925bdfdedf0f6421bc7eea8305f9002
Loading...
Loading
Loading...
Loading
Loading...
Loading
Multichain Portfolio | 34 Chains
| Chain | Token | Portfolio % | Price | Amount | Value |
|---|
Loading...
Loading
Loading...
Loading
A contract address hosts a smart contract, which is a set of code stored on the blockchain that runs when predetermined conditions are met. Learn more about addresses in our Knowledge Base.